program topog

c*    program to produce the two topographies used in
c*    the simplified geometry experiments of EISMINT
c*    Phase 2.

c*    Tony Payne, 6th March 1997.
 
      implicit none

      integer ew, ns, ewn, nsn

      parameter( ewn = 61, nsn = 61 )

      real slope, pi, w, ewd, nsd, ewm, nsm, dewns, 
     +     topg

c*    general constants 
      pi = 3.1416
      dewns = 25.0e3

      open(70,file='mound')
      open(80,file='trough')
      
c*    mound topography

c*    constants for mound topography
      slope = 250.0
      w = 150.0e3

      do ns = 1, nsn
      do ew = 1, ewn

         nsd = (ns-1) * dewns
         ewd = (ew-1) * dewns

         topg = abs(
     +          slope * sin(pi * ewd / w) +
     +          slope * cos(pi * nsd / w))

         write(70,10) ewd/1.0e3, nsd/1.0e3, topg

      end do
      end do

c*    trough topography
         
c*    constants for trough topography
      slope = -1.333e-3
      w = 200.0e3
      ewm = 750.0e3
      nsm = 750.0e3

      do ns = 1, nsn
      do ew = 1, ewn

         nsd = (ns-1) * dewns
         ewd = (ew-1) * dewns

         if ( ns .ge. 27 .and. ns .le. 35 .and.
     +        ew .ge. 31 .and. ew .le. 61 ) then

         topg = 1000.0 + 
     +          min(0.0, slope * (ewd - ewm) *
     +          cos(pi * (nsd - nsm) / w))

         else

         topg = 1000.0

         end if
         
         write(80,10) ewd/1.0e3, nsd/1.0e3, topg
         
      end do
      end do

10    format(3f12.4)

      close(70)
      close(80)
      
      end